読者です 読者をやめる 読者になる 読者になる

ごんれのラボ

iOS、Android、Adobe系ソフトの自動化スクリプトのことを書き連ねています。

画像ファイルのドキュメントサイズを調べて指定サイズより大きかったらFinderでタグをつける方法

概要

画像ファイルのドキュメントサイズを調べて指定サイズより大きかったら Finder でタグをつける AppleScript のドロップレットを書いた。
Photoshop を使っています。

検証バージョンは Photoshop CC 2017。

使い方

  1. AppleScriptのドロップレットを適当なところに置いておく
  2. ドキュメントサイズを調べたい Photoshop で対応している画像ファイルをドラッグ&ドロップする
  3. 指定したサイズだったら、ファイルに赤色のタグがつく

ソースコード

on open fileList
    repeat with i in fileList
        tell application id "com.adobe.photoshop"
            set oldUnits to ruler units of settings
            set ruler units of settings to mm units --mm にしてるけど、ピクセルで調べたかったらここ変える
            open i
            tell current document
                activate
                set filePath to POSIX path of (file path as alias)
                resize image resolution 350 resample method none
                --使うときはここのサイズを変更してください。mm で指定します。ピクセルで調べたかったら上のほうでルーラーの単位を変えつつ、ここでピクセル指定する
                if (width > 100 and height > 148) then
                    my addTagOnFile(filePath)
                else if (width > 148 and height > 100) then
                    my addTagOnFile(filePath)
                end if
                
                close saving no
            end tell
            set ruler units of settings to oldUnits
        end tell
    end repeat
end open

to addTagOnFile(filePath)
    do shell script "xattr -w com.apple.metadata:_kMDItemUserTags '(\"レッド\\n6\")' " & filePath
end addTagOnFile

注意点

サーバーにあるファイルにタグがつかないことがあったので、ローカルにコピーして実行したほうがいいかも。

もっと詳しく

要望があれば、Twitter にて。